1: module List=
 2:     (* Execution: fast, Output: least intuitive *)
 3:     let split s = 
 4:         let rec loop = function
 5:         | (_,[],a,b) -> (a,b)
 6:         | (true,h::t,a,b) -> loop(false,t,h::a,b)
 7:         | (false,h::t,a,b)-> loop (true,t,a,h::b)
 8:         in loop(true,s,[],[])
 9:     (* Execution: slowest, Output: most intuitive *)
10:     let split1 s =
11:         let len = List.length s in
12:         s |> List.mapi (fun i x -> (i<len/2,x))
13:           |> List.partition fst
14:           |> (fun (x,y) -> ((x |> List.map snd),(y |> List.map snd)))
15:     (* Execution: average, Output: fairly intuitive *)
16:     let split2 s =
17:          let len = List.length s in
18:          s |> List.fold (fun (n,(a,b)) x -> 
19:             (n+1,if n <(len/2) then (x::a,b) else (a,x::b)))
20:                   (0,([],[]))
21:            |> snd
22:     (* Execution: quite fast, Output: short and elegant *)
23:     let split3 s = List.fold (fun (xs, ys) e -> (e::ys, xs)) ([], []) s
24:     (* Execution: fastest, Output: fairly intuitive, but inner function needed *)
25:     let split4 s =
26:         let rec loop l (xs, ys) =
27:             match l with
28:             | x::y::rest -> loop rest (x::xs, y::ys)
29:             | [x] -> (x::xs, ys)
30:             | _ -> (xs, ys)
31:         loop s ([], [])
32:             
33: 
34: Timing function
35: 
36: let l = [1..10000000]
37: 
38: printfn "%d" (timeit List.split l)
39: printfn "%d" (timeit List.split1 l)
40: printfn "%d" (timeit List.split2 l)
41: printfn "%d" (timeit List.split3 l)
42: printfn "%d" (timeit List.split4 l)
43: 
44: (*
45: Results:
46: List.split:  1234ms
47: List.split1: 5242ms
48: List.split2: 3235ms
49: List.split3: 2754ms
50: List.split4: 1068ms
51: *)
52: 
53: (*
54: > List.split [1..10];;
55: val it : int list * int list = ([9; 7; 5; 3; 1], [10; 8; 6; 4; 2])
56: > List.split1 [1..10];;
57: val it : int list * int list = ([1; 2; 3; 4; 5], [6; 7; 8; 9; 10])
58: > List.split2 [1..10];;
59: val it : int list * int list = ([5; 4; 3; 2; 1], [10; 9; 8; 7; 6])
60: > List.split3 [1..10];;
61: val it : int list * int list = ([10; 8; 6; 4; 2], [9; 7; 5; 3; 1])
62: > List.split4 [1..10];;
63: val it : int list * int list = ([9; 7; 5; 3; 1], [10; 8; 6; 4; 2])
64: > 
65: *)